Archive for May, 2004

It’s been awhile since I’ve posted any actual code. Most of the coding I’ve been doing this month has been in KiXtart. Most people will undoubtedly have not heard of “KiX” (the short form).

KiX is essentially DOS, on speed, for network admins of Microsoft networks. It has some pretty impressive functions. Normally it’s used as a login-script replacement. Some of what I’ve done has been in that space, other things I’ve done have been remote-execution scripts.

This script is for upgrading from ZENWorks 3.2 client to ZENWorks 4.0. It will also install the client if you don’t have one, and fulfills any pre-requisites that you might be missing.

Here’s the script:

; ZEN upgrade script - April 27, 2004
; Written by Jeremy C. Wright for the Health Sciences Centre

;**************************************************************
;
; EXECUTION CODE
;
;**************************************************************

GOSUB "setVals"
GOSUB "greetUser"

IF checkZenInstall ()=1
	tellUser ("nochange")
	EXIT
ENDIF

IF checkIEInstall ()=0
	GOSUB "doIEInstall"
ELSE
	GOSUB "doZenInstall"
ENDIF

tellUser ("nochange")
EXIT

;**************************************************************
;
; SUBROUTINES
;
;**************************************************************

:setVals
	; set the program and environment variables before initializing
	; BREAK OFF
	SetConsole ("SHOW")
	SetConsole ("MAXIMIZE")
	SetConsole ("FOREGROUND")
	SetConsole ("ALWAYSONTOP")
	CLS
RETURN

:greetUser
	; Initial comments to thank user for being patient
	? "This script will ensure you have ZENWorks properly installed."
	?
	? "Please be patient while this runs."
	?
	?
RETURN

:doIEInstall
	; Perform Installation of IE
	RUN "\\hscxntdb0012\ZenAgent\ie6install.bat"
	tellUser ("doingie")
	EXIT
RETURN

:doZenInstall
	; Perform Installation of ZENWorks
	RUN "\\hscxntdb0012\ZenAgent\zeninstall.bat"
	tellUser ("doingzen")
	EXIT
RETURN

;**************************************************************
;
; FUNCTIONS
;
;**************************************************************

FUNCTION checkZenInstall ()
	; Ensures ZENWorks is properly installed
	IF Exist ("C:\Program Files\Novell\Zenworks\zennw32.dll")
		$checkZenInstall=1
		RETURN
	ELSE
		$checkZenInstall=0
		RETURN
	END IF
	$checkZenInstall=0
ENDIF

ENDFUNCTION

FUNCTION checkIEInstall ()
	; Checks for the location of iexplore.exe on C and D, and checks version info
	IF Exist ("C:\Program Files\Internet Explorer\iexplore.exe")
		IF GetFileVersion ("C:\Program Files\Internet Explorer\iexplore.exe") < 6
			$checkIEInstall=0
			RETURN
		ENDIF
	ENDIF

	IF Exist ("D:\Program Files\Internet Explorer\iexplore.exe")
		IF GetFileVersion ("D:\Program Files\Internet Explorer\iexplore.exe") < 6
			$checkIEInstall=0
			RETURN
		ENDIF
	ENDIF
	$checkIEInstall=1
ENDFUNCTION

FUNCTION tellUser ($msgIn)
	IF $msgIn="nochange"
		?
		?
		? "Your system is up to date, have a nice day."
		?
		?
		RETURN
	ENDIF

	IF $msgIn="doingzen"
		?
		?
		? "We are now installing ZENWorks. Your computer WILL reboot."
		?
		?
		MESSAGEBOX ("Please wait... Your machine WILL reboot.","Installing...",48)
		RETURN
	ENDIF

	IF $msgIn="doingie"
		?
		?
		? "We are now installing Internet Explorer 6. Your computer WILL reboot."
		?
		?
		MESSAGEBOX ("Please wait... Your machine WILL reboot.","Installing...",48)
		RETURN
	ENDIF
ENDFUNCTION

To provide context, it's called in this manner:

IF INGROUP ("DESKTOP")
	IF @INWIN = 1
;		? "Windows NT Version is " + @DOS
	? "Updated Script, shouldn't run on 9x boxes"
		SLEEP 5
		CALL "ZENUPGRADE.KIX"
	ENDIF
ENDIF

The reason for the "INGROUP ("DESKTOP")" is that the "DESKTOP" group is our Global Group which assigns local admin rights. We can temporarily add users to this group, in which case the next time they login it'll run. Then we can remove them at a later date.

So far we've been adding 2-3 letters worth of users per day (about 500 users on average); and then removing 2-3 of the oldest letters.

Over the next week I'll also release scripts to convert clients from one print server to another, and to point clients at a local Software Update Services server.

Have a great weekend!